#version 3.0

camera {
  location <0, 0.2, -1>
  look_at <0, 0, 0>
}

plane {
  y, 0
  pigment {color rgb<0, 0, 0>}
  finish {
    reflection 1
    ambient 0
    diffuse 0
  }
  normal {
    bumps 0.1
    scale <0.03, 0.01, 0.01>
    rotate <0, -25, 0>
    translate <51, 0, 37>
  }
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.25 color rgb<0.80, 0.50, 0.00>]
      [0.50 color rgb<0.20, 0.12, 0.00>]
      [0.70 color rgb<0.00, 0.00, 0.00>]
    }
    scale 2
    translate -1
  }
  rotate<-25,  0, 0>
}

sphere {<0, 0, 0>, 2
  pigment {color rgbt<1, 1, 1, 1>}
  halo {
    emitting
    spherical_mapping
    linear
    color_map {
      [ 0.00 color rgbt<0.70, 0.45, 0.00, 1.0> ]
      [ 0.82 color rgbt<1.00, 0.70, 0.00,-0.5> ]
      [ 0.84 color rgbt<1.00, 1.00, 0.50,  -1> ]
      [ 1.00 color rgbt<1.00, 1.00, 1.00,  -1> ]
    }
    scale 0.5
    samples 10
  }
  hollow
  scale <3000, 3000, 2000>
  translate<0, 300, 3000>
}

#declare HField =  height_field {
  gif "hfield.gif"
  water_level 0.001
  translate<-0.5, -0.001, -0.5>
  pigment {color rgb<0.80, 0.50, 0.00>}
  finish {ambient 0.18 diffuse 0.0}
}

object {
  HField
  scale<80, 4, 80>
  rotate<0, 150, 0>
  translate<50, 0, 100>
}
object {
  HField
  scale<20, 4, 20>
  rotate<0, 90, 0>
  translate<22, 0, 100>
}
object {
  HField
  scale<8, 4, 8>
  rotate<0, 90, 0>
  translate<14, 0, 100>
}
object {
  HField
  scale<4, 4, 4>
  rotate<0, 90, 0>
  translate<12, 0, 100>
}
object {
  HField
  scale<2, 3, 2>
  rotate<0, 90, 0>
  translate<8.5, 0, 100>
}
object {
  HField
  scale<1, 2, 1>
  rotate<0, 0, 0>
  translate<6, 0, 100>
}

object {
  HField
  scale<1, 0.1, 0.5>
  rotate<0, 50, 0>
  translate<0.5, -0.02, -0.1>
  finish {ambient 0}
}

object {
  HField
  scale<1, 0.12, 0.2>
  rotate<0, 200, 0>
  translate<-0.3, -0.02, -0.62>
  finish {ambient 0}
}

object {
  HField
  rotate<0, 210, 0>
  scale<3.5, 0.4, 2>
  translate<-2, -0.01, 2>
  finish {ambient 0}
}

#declare Boat = union {
  prism {linear_sweep linear_spline 0, 1, 15,
    <  0,  0>, <243,  0>, <246, 41>, <203, 33>, <167, 28>, <157, 51>,
    <123, 49>, <123, 23>, <104, 20>, < 77, 18>, < 43, 19>, <  5, 24>,
    <  4, 19>, <  0, 20>, <  0,  0>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <128,  47>, <127, 110>, <124, 110>, <125,  47>, <128,  47>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <126, 58>, < 98, 58>, < 98, 56>, <126, 56>, <126, 58>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <156,  49>, <139, 135>, <137, 135>, <154,  49>, <156,  49>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <126,  22>, < 58, 125>, < 56, 125>, <124,  22>, <126,  22>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <126, 99>, <228, 29>, <228, 28>, <126, 98>, <126, 99>
  }
  prism {linear_sweep linear_spline 0, 1, 5,
    <242, 33>, <262,  0>, <260, 0>, <240, 33>, <242, 33>
  }
  pigment {color rgb<0.80, 0.50, 0.00>}
  finish {ambient 0 diffuse 0}
  rotate <-90, 0, 0>
  scale <0.004, 0.005, 0.004>
}

object {
  Boat
  translate<0.9, -0.01, 5>
}